blob: 7133d57da8d93fd42f8add87eb057d428fd8fd75 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
|
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$
EAPI=5
PYTHON_COMPAT=( python2_7 )
inherit eutils toolchain-funcs cmake-utils python-single-r1
MYPN=InsightToolkit
MYP=${MYPN}-${PV}
DESCRIPTION="NLM Insight Segmentation and Registration Toolkit"
HOMEPAGE="http://www.itk.org"
SRC_URI="
mirror://sourceforge/${PN}/${MYP}.tar.gz
doc? ( mirror://sourceforge/${PN}/Doxygen${MYPN}-4.4.0.tar.gz )"
RESTRICT="primaryuri"
LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
IUSE="debug doc examples fftw itkv3compat python review cpu_flags_x86_sse2 test vtkglue"
RDEPEND="
sci-libs/hdf5[cxx]
virtual/jpeg
media-libs/libpng
media-libs/tiff:0
sys-libs/zlib
fftw? ( sci-libs/fftw:3.0 )
vtkglue? ( sci-libs/vtk )
"
DEPEND="${RDEPEND}
python? ( ${PYTHON_DEPS}
>=dev-lang/swig-2.0
>=dev-cpp/gccxml-0.9.0_pre20120309 )
doc? ( app-doc/doxygen )
"
S="${WORKDIR}/${MYP}"
pkg_pretend() {
if [[ -z ${ITK_COMPUTER_MEMORY_SIZE} ]]; then
elog "To tune ITK to make the best use ouf working memory you can set"
elog " ITK_COMPUTER_MEMORY_SIZE=XX"
elog "in make.conf, default is 1 (unit is GB)"
fi
if use python && [[ -z ${ITK_WRAP_DIMS} ]]; then
elog "For Python language bindings, you can define the dimensions"
elog "you want to create bindings for by setting"
elog " ITK_WRAP_DIMS=X;Y;Z..."
elog "in make.conf, default is 2;3 for 2D and 3D data"
fi
}
src_configure() {
local mycmakeargs=(
-DWRAP_ITK_JAVA=OFF
-DWRAP_ITK_TCL=OFF
-DITK_USE_SYSTEM_HDF5=ON
-DITK_USE_SYSTEM_JPEG=ON
-DITK_USE_SYSTEM_PNG=ON
-DITK_USE_SYSTEM_TIFF=ON
-DITK_USE_SYSTEM_ZLIB=ON
-DITK_USE_SYSTEM_GCCXML=ON
-DITK_USE_SYSTEM_SWIG=ON
-DITK_BUILD_ALL_MODULES=ON
-DBUILD_SHARED_LIBS=ON
-DBUILD_EXAMPLES=OFF
-DITK_COMPUTER_MEMORY_SIZE="${ITK_COMPUTER_MEMORY_SIZE:-1}"
$(cmake-utils_use_build test TESTING)
$(cmake-utils_use review ITK_USE_REVIEW)
$(cmake-utils_use itkv3compat ITKV3_COMPATIBILITY)
$(cmake-utils_use cpu_flags_x86_sse2 VNL_CONFIG_ENABLE_SSE2)
)
if use fftw; then
mycmakeargs+=(
-DUSE_FFTWD=ON
-DUSE_FFTWF=ON
-DUSE_SYSTEM_FFTW=ON
-DITK_WRAP_double=ON
-DITK_WRAP_vector_double=ON
-DITK_WRAP_covariant_vector_double=ON
-DITK_WRAP_complex_double=ON
)
fi
if use vtkglue; then
mycmakeargs+=(
-DModule_ITKVtkGlue=ON
)
fi
if use python; then
mycmakeargs+=(
-DITK_WRAP_PYTHON=ON
-DITK_WRAP_DIMS="${ITK_WRAP_DIMS:-2;3}"
)
else
mycmakeargs+=(
-DITK_WRAP_PYTHON=OFF
)
fi
cmake-utils_src_configure
}
src_install() {
cmake-utils_src_install
if use examples; then
insinto /usr/share/doc/${PF}/examples
docompress -x /usr/share/doc/${PF}/examples
doins -r "${S}"/Examples/*
fi
echo "ITK_DATA_ROOT=${EROOT}/usr/share/${PN}/data" > ${T}/40${PN}
local ldpath="${EROOT}/usr/$(get_libdir)/InsightToolkit"
if use python; then
echo "PYTHONPATH=${EROOT}/usr/$(get_libdir)/InsightToolkit/WrapITK/Python" >> ${T}/40${PN}
ldpath="${ldpath}:${EROOT}/usr/$(get_libdir)/InsightToolkit/WrapITK/lib"
fi
echo "LDPATH=${ldpath}" >> ${T}/40${PN}
if use doc; then
insinto "/usr/share/doc/${PF}/api-docs"
cd "${WORKDIR}"/html
rm -f *.md5 || die "Failed to remove superfluous hashes"
einfo "Installing API docs. This may take some time."
insinto "/usr/share/doc/${PF}/api-docs"
doins -r ./* || die "Failed to install docs"
fi
doenvd "${T}"/40${PN}
}
|
GitWeb