# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=2

E_SNAP_DATE="2009-06-14"
inherit enlightenment libtool

DESCRIPTION="hardware-accelerated canvas API"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"

IUSE="altivec cairo directfb edb +eet fbcon +fontconfig gif +jpeg
	mmx opengl +png sdl sse svg threads tiff X xcb xpm"

RDEPEND="=dev-libs/eina-0.0.2.061
	media-libs/freetype
	fontconfig? ( media-libs/fontconfig )
	X? ( x11-libs/libXrender )
	sdl? ( media-libs/libsdl )
	opengl? ( virtual/opengl )
	gif? ( media-libs/giflib )
	png? ( media-libs/libpng )
	jpeg? ( media-libs/jpeg )
	eet? ( dev-libs/eet )
	edb? ( dev-db/edb )
	tiff? ( media-libs/tiff )
	xpm? ( x11-libs/libXpm )
	svg? ( >=gnome-base/librsvg-2.22.2 )
	xcb? ( >=x11-libs/xcb-util-0.2 )
	directfb? ( dev-libs/DirectFB )"

DEPEND=">=dev-util/pkgconfig-0.9.0
	X? (
		x11-proto/xextproto
		x11-proto/xproto
	)"

src_prepare() {
	# Required for cross-compilation
	elibtoolize
}

src_configure() {
	econf \
	$(use_enable fontconfig) \
	$(use_enable X      software-x11) \
	$(use_enable X      software-16-x11) \
	$(use_enable xcb    software-xcb) \
	$(use_enable sdl    software-sdl) \
	$(use_enable sdl    sdl-primitive) \
	$(use_enable fbcon  fb) \
	$(use_enable opengl gl-x11) \
	$(use_enable X      xrender-x11) \
	$(use_enable xcb    xrender-xcb) \
	$(use_enable gif    image-loader-gif) \
	$(use_enable png    image-loader-png) \
	$(use_enable jpeg   image-loader-jpeg) \
	$(use_enable eet    image-loader-eet) \
	$(use_enable eet    font-loader-eet) \
	$(use_enable edb    image-loader-edb) \
	$(use_enable tiff   image-loader-tiff) \
	$(use_enable xpm    image-loader-xpm) \
	$(use_enable svg    image-loader-svg) \
	$(use_enable threads pthreads) \
	$(use_enable mmx     cpu-mmx) \
	$(use_enable sse     cpu-sse) \
	$(use_enable altivec cpu-altivec) \
	$(use_enable directfb) \
	--enable-buffer \
	--disable-cairo-x11 \
	--disable-image-loader-pmaps \
	--enable-cpu-c \
	--enable-scale-sample \
	--enable-scale-smooth \
	--enable-convert-8-rgb-332 \
	--enable-convert-8-rgb-666 \
	--enable-convert-8-rgb-232 \
	--enable-convert-8-rgb-222 \
	--enable-convert-8-rgb-221 \
	--enable-convert-8-rgb-121 \
	--enable-convert-8-rgb-111 \
	--enable-convert-16-rgb-565 \
	--enable-convert-16-rgb-555 \
	--enable-convert-16-rgb-444 \
	--enable-convert-16-rgb-rot-0 \
	--enable-convert-16-rgb-rot-270 \
	--enable-convert-16-rgb-rot-90 \
	--enable-convert-24-rgb-888 \
	--enable-convert-24-bgr-888 \
	--enable-convert-32-rgb-8888 \
	--enable-convert-32-rgbx-8888 \
	--enable-convert-32-bgr-8888 \
	--enable-convert-32-bgrx-8888 \
	--enable-convert-32-rgb-rot-0 \
	--enable-convert-32-rgb-rot-270 \
	--enable-convert-32-rgb-rot-90	 \
	--x-includes=${SYSROOT}/usr/X11R6/include \
	--x-libraries=${SYSROOT}/usr/X11R6/lib
}

src_compile() {
	emake || enlightenment_die "emake failed"
	use doc && [[ -x ./gendoc ]] && { ./gendoc || enlightenment_die "gendoc failed" ; }
}