blob: ae9e23ec02d73c1eace6160745af3205ea0b556f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
|
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-gfx/xloadimage/xloadimage-4.1-r10.ebuild,v 1.12 2011/08/25 20:51:13 dilfridge Exp $
EAPI=2
inherit eutils toolchain-funcs
DESCRIPTION="utility to view many different types of images under X11"
HOMEPAGE="http://world.std.com/~jimf/xloadimage.html"
SRC_URI="ftp://ftp.x.org/R5contrib/${P/-/.}.tar.gz
mirror://gentoo/${P}-gentoo.diff.bz2"
LICENSE="MIT"
SLOT="0"
KEYWORDS="alpha amd64 arm hppa ia64 ~mips ppc ppc64 sh sparc x86 ~x86-fbsd"
IUSE="tiff jpeg png"
RDEPEND="x11-libs/libX11
tiff? ( media-libs/tiff )
png? ( media-libs/libpng )
jpeg? ( virtual/jpeg:0 )"
DEPEND="${RDEPEND}
!media-gfx/xli"
S=${WORKDIR}/${P/-/.}
src_prepare() {
epatch "${WORKDIR}"/${P}-gentoo.diff
epatch "${FILESDIR}"/${P}-zio-shell-meta-char.diff
epatch "${FILESDIR}"/${P}-endif.patch
# Do not define errno extern, but rather include errno.h
# <azarah@gentoo.org> (1 Jan 2003)
epatch "${FILESDIR}"/${P}-include-errno_h.patch
epatch "${FILESDIR}"/xloadimage-gentoo.patch
sed -i -e "s:OPT_FLAGS=:OPT_FLAGS=$CFLAGS:" Make.conf || die
sed -i -e "s:^#include <varargs.h>:#include <stdarg.h>:" rlelib.c || die
# On FreeBSD systems malloc.h is a false header asking for fixes.
# On MacOSX it would require malloc/malloc.h
# On other systems it's simply unneeded
sed -i -e 's,<malloc.h>,<stdlib.h>,' vicar.c || die
epatch "${FILESDIR}"/${P}-unaligned-access.patch
epatch "${FILESDIR}"/${P}-ldflags_and_exit.patch
sed -i \
-e 's:png_set_gray_1_2_4_to_8:png_set_expand_gray_1_2_4_to_8:' \
png.c || die
# One of the previous patches screws up a bracket...
epatch "${FILESDIR}"/${P}-bracket.patch
chmod +x configure
}
src_configure() {
tc-export CC
econf
}
src_install() {
dobin xloadimage uufilter || die
dosym xloadimage /usr/bin/xsetbg || die
dosym xloadimage /usr/bin/xview || die
insinto /etc/X11
doins xloadimagerc || die
newman xloadimage.man xloadimage.1 || die
newman uufilter.man uufilter.1 || die
echo ".so man1/xloadimage.1" > "${T}"/xsetbg.1
doman "${T}"/xsetbg.1 || die
newman "${T}"/xsetbg.1 xview.1 || die
dodoc README
}
|
GitWeb