app-shells/tcsh/tcsh-6.14-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-shells/tcsh/tcsh-6.14-r1.ebuild,v 1.1 2005/09/30 19:42:05 grobian Exp $

MY_P="${P}.00"
DESCRIPTION="Enhanced version of the Berkeley C shell (csh)"
HOMEPAGE="http://www.tcsh.org/"
SRC_URI="ftp://ftp.astron.com/pub/tcsh/${MY_P}.tar.gz
	mirror://gentoo/${P}-conffiles.tar.bz2"
# note: starting from this version the various files scattered around
#       the place in ${FILESDIR} are now stored in a versioned tarball

LICENSE="BSD"
SLOT="0"
KEYWORDS="~x86 ~ppc ~sparc ~alpha ~arm ~hppa ~amd64 ~ia64 ~ppc64 ~mips"
IUSE="perl"

RDEPEND="virtual/libc
	>=sys-libs/ncurses-5.1
	perl? ( dev-lang/perl )"

S="${WORKDIR}/${MY_P}"


src_compile() {
	econf --prefix=/ || die "econf failed"
	emake || die "compile problem"
}

src_install() {
	make DESTDIR=${D} install install.man || die

	if use perl ; then
		perl tcsh.man2html || die
		dohtml tcsh.html/*.html
	fi

	dosym /bin/tcsh /bin/csh
	dodoc FAQ Fixes NewThings Ported README WishList Y2K

	insinto /etc
	doins ${WORKDIR}/gentoo/csh.cshrc
	doins ${WORKDIR}/gentoo/csh.login

	insinto /etc/skel
	newins ${WORKDIR}/gentoo/tcsh.config .tcsh.config

	insinto /etc/profile.d
	doins ${WORKDIR}/gentoo/tcsh-bindkey.csh
	doins ${WORKDIR}/gentoo/tcsh-settings.csh
	doins ${WORKDIR}/gentoo/tcsh-aliases
	doins ${WORKDIR}/gentoo/tcsh-complete
	doins ${WORKDIR}/gentoo/tcsh-gentoo_legacy
}

pkg_postinst() {
	while read line; do einfo "${line}"; done <<EOF
The default behaviour of tcsh has significantly changed starting from
this ebuild.  In contrast to previous ebuilds, the amount of
customisation to the default shell's behaviour has been reduced to a
bare minimum (a customised prompt).
If you rely on the customisations provided by previous ebuilds, you will
have to copy over the relevant (now commented out) parts to your own
~/.tcshrc.  Please check all tcsh-* files in /etc/profiles.d/ and add
sourceing of /etc/profiles.d/tcsh-complete to restore previous
behaviour.
Please note that the tcsh-complete file is a large set of examples that
is not meant to be used in its exact form, as it defines an excessive --
sometimes conflicting -- amount of completion scripts.  It is highly
encouraged to copy over the desired auto completion scripts to the
personal ~/.tcshrc file.  The tcsh-complete file is not any longer
sourced by the default system scripts.
EOF
}