From a850209c6227ffee325c8a50ea56d8f111c284ff Mon Sep 17 00:00:00 2001
From: Ian Delaney <idella4@gentoo.org>
Date: Thu, 7 Mar 2013 15:38:09 +0000
Subject: Drop old, re-migrated 0.8.1 to distutils-r1

(Portage version: 2.1.11.40/cvs/Linux x86_64, signed Manifest commit with key 0xB8072B0D)
---
 dev-python/http-parser/ChangeLog                   |  8 ++++-
 dev-python/http-parser/http-parser-0.7.5.ebuild    | 35 ------------------
 dev-python/http-parser/http-parser-0.8.1-r1.ebuild | 42 ++++++++++++++++++++++
 3 files changed, 49 insertions(+), 36 deletions(-)
 delete mode 100644 dev-python/http-parser/http-parser-0.7.5.ebuild
 create mode 100644 dev-python/http-parser/http-parser-0.8.1-r1.ebuild

(limited to 'dev-python/http-parser')

diff --git a/dev-python/http-parser/ChangeLog b/dev-python/http-parser/ChangeLog
index 4f5b3c3af79e..16addaaf445e 100644
--- a/dev-python/http-parser/ChangeLog
+++ b/dev-python/http-parser/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-python/http-parser
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/http-parser/ChangeLog,v 1.11 2013/02/22 05:31:21 patrick Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/http-parser/ChangeLog,v 1.12 2013/03/07 15:38:09 idella4 Exp $
+
+*http-parser-0.8.1-r1 (07 Mar 2013)
+
+  07 Mar 2013; Ian Delaney <idella4@gentoo.org> +http-parser-0.8.1-r1.ebuild,
+  -http-parser-0.7.5.ebuild:
+  Drop old, re-migrated 0.8.1 to distutils-r1
 
 *http-parser-0.8.1 (22 Feb 2013)
 
diff --git a/dev-python/http-parser/http-parser-0.7.5.ebuild b/dev-python/http-parser/http-parser-0.7.5.ebuild
deleted file mode 100644
index b664484ea075..000000000000
--- a/dev-python/http-parser/http-parser-0.7.5.ebuild
+++ /dev/null
@@ -1,35 +0,0 @@
-# Copyright 1999-2012 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/http-parser/http-parser-0.7.5.ebuild,v 1.1 2012/06/07 18:09:36 xarthisius Exp $
-
-EAPI=4
-
-SUPPORT_PYTHON_ABIS=1
-RESTRICT_PYTHON_ABIS="*-jython"
-
-inherit distutils
-
-DESCRIPTION="HTTP request/response parser for python in C"
-HOMEPAGE="http://github.com/benoitc/http-parser"
-SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="examples"
-
-RDEPEND=""
-DEPEND="${RDEPEND}
-	dev-python/setuptools
-	dev-python/cython"
-
-PYTHON_CFLAGS=("2.* + -fno-strict-aliasing")
-
-src_install() {
-	distutils_src_install
-	if use examples; then
-		docompress -x usr/share/doc/${P}/examples
-		insinto usr/share/doc/${P}
-		doins -r examples/
-	fi
-}
diff --git a/dev-python/http-parser/http-parser-0.8.1-r1.ebuild b/dev-python/http-parser/http-parser-0.8.1-r1.ebuild
new file mode 100644
index 000000000000..22a97af14733
--- /dev/null
+++ b/dev-python/http-parser/http-parser-0.8.1-r1.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/http-parser/http-parser-0.8.1-r1.ebuild,v 1.1 2013/03/07 15:38:09 idella4 Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_6,2_7,3_1,3_2} pypy{1_9,2_0} )
+
+inherit distutils-r1 flag-o-matic
+
+DESCRIPTION="HTTP request/response parser for python in C"
+HOMEPAGE="http://github.com/benoitc/http-parser"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="examples"
+
+RDEPEND=""
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/cython"
+
+python_compile() {
+	if [[ ${EPYTHON} != python3* ]]; then
+		local CFLAGS=${CFLAGS}
+		append-cflags -fno-strict-aliasing
+	fi
+
+	distutils-r1_python_compile
+}
+
+python_install_all() {
+	dodoc README.rst
+
+	if use examples; then
+		docompress -x usr/share/doc/${P}/examples
+		insinto usr/share/doc/${P}
+		doins -r examples/
+	fi
+}
-- 
cgit v1.2.3-65-gdbad