1 files changed, 58 insertions, 0 deletions
diff --git a/app-shells/dash/dash-0.5.7.3-r1.ebuild b/app-shells/dash/dash-0.5.7.3-r1.ebuild
new file mode 100644
index 000000000000..d49881531501
--- /dev/null
+++ b/app-shells/dash/dash-0.5.7.3-r1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-shells/dash/dash-0.5.7.3-r1.ebuild,v 1.1 2012/12/21 04:48:26 vapier Exp $
+
+EAPI="4"
+
+inherit autotools eutils flag-o-matic toolchain-funcs
+
+DEB_PV=${PV%.*}
+DEB_PATCH=${PV##*.}
+DEB_PF="${PN}_${DEB_PV}-${DEB_PATCH}"
+MY_P="${PN}-${DEB_PV}"
+
+DESCRIPTION="DASH is a direct descendant of the NetBSD version of ash (the Almquist SHell) and is POSIX compliant"
+HOMEPAGE="http://gondor.apana.org.au/~herbert/dash/"
+SRC_URI="http://gondor.apana.org.au/~herbert/dash/files/${PN}-${DEB_PV}.tar.gz
+	mirror://debian/pool/main/d/dash/${DEB_PF}.diff.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+IUSE="libedit static"
+
+RDEPEND="!static? ( libedit? ( dev-libs/libedit ) )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	libedit? ( static? ( dev-libs/libedit[static-libs] ) )"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	epatch "${WORKDIR}"/${DEB_PF}.diff
+	epatch */debian/diff/*
+	epatch "${FILESDIR}"/${PN}-0.5.5.1-octal.patch #337329
+
+	# Fix the invalid sort
+	sed -i -e 's/LC_COLLATE=C/LC_ALL=C/g' src/mkbuiltins
+
+	# Use pkg-config for libedit linkage
+	sed -i "/LIBS/s:-ledit:\`$(tc-getPKG_CONFIG) --libs libedit $(usex static --static '')\`:" configure.ac
+
+	# May as well, as the debian patches force this anyway
+	eautoreconf
+}
+
+src_configure() {
+	use static && append-ldflags -static
+	# Do not pass --enable-glob due to #443552.
+	econf \
+		--bindir=/bin \
+		--enable-fnmatch \
+		$(use_with libedit)
+}
+
+src_install() {
+	default
+	dodoc */debian/changelog
+}