revbump ebuilds to support multilib-build, changes reviewed by aballier

(Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key 2B6559ED)

3 files changed, 63 insertions, 24 deletions

diff --git a/x11-libs/libva-vdpau-driver/ChangeLog b/x11-libs/libva-vdpau-driver/ChangeLog
index 2b22818bf281..fa8c416cbdc7 100644
--- a/x11-libs/libva-vdpau-driver/ChangeLog
+++ b/x11-libs/libva-vdpau-driver/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for x11-libs/libva-vdpau-driver
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-libs/libva-vdpau-driver/ChangeLog,v 1.4 2013/05/03 22:18:18 jlec Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/libva-vdpau-driver/ChangeLog,v 1.5 2014/02/01 15:24:44 axs Exp $
+
+*libva-vdpau-driver-0.7.4-r1 (01 Feb 2014)
+
+  01 Feb 2014; Ian Stakenvicius (_AxS_) <axs@gentoo.org>
+  +libva-vdpau-driver-0.7.4-r1.ebuild, libva-vdpau-driver-9999.ebuild:
+  revbump ebuilds to support multilib-build, changes reviewed by aballier
 
   03 May 2013; Justin Lecher <jlec@gentoo.org> libva-vdpau-driver-0.7.4.ebuild,
   metadata.xml:
@@ -111,4 +117,3 @@
   +vdpau-video-0.6.9.ebuild, +metadata.xml:
   initial import, bug #317317, ebuild by Frank Richter
   <res@crystalspace3d.org> with small modifications by me
-
diff --git a/x11-libs/libva-vdpau-driver/libva-vdpau-driver-0.7.4-r1.ebuild b/x11-libs/libva-vdpau-driver/libva-vdpau-driver-0.7.4-r1.ebuild
new file mode 100644
index 000000000000..40901940513d
--- /dev/null
+++ b/x11-libs/libva-vdpau-driver/libva-vdpau-driver-0.7.4-r1.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/libva-vdpau-driver/libva-vdpau-driver-0.7.4-r1.ebuild,v 1.1 2014/02/01 15:24:44 axs Exp $
+
+EAPI=5
+
+AUTOTOOLS_AUTORECONF="yes"
+inherit autotools-multilib eutils
+
+DESCRIPTION="VDPAU Backend for Video Acceleration (VA) API"
+HOMEPAGE="http://www.freedesktop.org/wiki/Software/vaapi"
+SRC_URI="http://www.freedesktop.org/software/vaapi/releases/libva-vdpau-driver/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug opengl"
+
+RDEPEND=">=x11-libs/libva-1.1.0[X,opengl?,${MULTILIB_USEDEP}]
+	opengl? ( virtual/opengl[${MULTILIB_USEDEP}] )
+	x11-libs/libvdpau[${MULTILIB_USEDEP}]
+	!x11-libs/vdpau-video"
+
+DEPEND="${DEPEND}
+	virtual/pkgconfig"
+
+DOCS=( NEWS README AUTHORS )
+
+src_prepare() {
+	epatch "${FILESDIR}/${P}-glext-missing-definition.patch"
+	sed -i 's/AM_CONFIG_HEADER/AC_CONFIG_HEADERS/g' configure.ac || die
+	autotools-multilib_src_prepare
+}
+
+multilib_src_configure() {
+	local myeconfargs=(
+		$(use_enable debug)
+		$(use_enable opengl glx)
+	)
+	autotools-utils_src_configure
+}
diff --git a/x11-libs/libva-vdpau-driver/libva-vdpau-driver-9999.ebuild b/x11-libs/libva-vdpau-driver/libva-vdpau-driver-9999.ebuild
index 9fe5110c63fd..07762a0ba4db 100644
--- a/x11-libs/libva-vdpau-driver/libva-vdpau-driver-9999.ebuild
+++ b/x11-libs/libva-vdpau-driver/libva-vdpau-driver-9999.ebuild
@@ -1,8 +1,8 @@
-# Copyright 1999-2012 Gentoo Foundation
+# Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/x11-libs/libva-vdpau-driver/libva-vdpau-driver-9999.ebuild,v 1.1 2012/11/21 17:53:31 aballier Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/libva-vdpau-driver/libva-vdpau-driver-9999.ebuild,v 1.2 2014/02/01 15:24:44 axs Exp $
 
-EAPI=4
+EAPI=5
 
 SCM=""
 if [ "${PV%9999}" != "${PV}" ] ; then # Live ebuild
@@ -10,8 +10,8 @@ if [ "${PV%9999}" != "${PV}" ] ; then # Live ebuild
 	EGIT_BRANCH=master
 	EGIT_REPO_URI="git://anongit.freedesktop.org/vaapi/vdpau-driver"
 fi
-
-inherit autotools ${SCM}
+AUTOTOOLS_AUTORECONF="yes"
+inherit autotools-multilib ${SCM}
 
 DESCRIPTION="VDPAU Backend for Video Acceleration (VA) API"
 HOMEPAGE="http://www.freedesktop.org/wiki/Software/vaapi"
@@ -31,27 +31,20 @@ else
 fi
 IUSE="debug opengl"
 
-RDEPEND=">=x11-libs/libva-1.1.0[X,opengl?]
-	opengl? ( virtual/opengl )
-	x11-libs/libvdpau
+RDEPEND=">=x11-libs/libva-1.1.0[X,opengl?,${MULTILIB_USEDEP}]
+	opengl? ( virtual/opengl[${MULTILIB_USEDEP}] )
+	x11-libs/libvdpau[${MULTILIB_USEDEP}]
 	!x11-libs/vdpau-video"
 
 DEPEND="${DEPEND}
 	virtual/pkgconfig"
 
-src_prepare() {
-	eautoreconf
-}
+DOCS=( NEWS README AUTHORS )
 
-src_configure() {
-	econf \
-		--disable-silent-rules \
-		$(use_enable debug) \
+multilib_src_configure() {
+	local myeconfargs=(
+		$(use_enable debug)
 		$(use_enable opengl glx)
-}
-
-src_install() {
-	emake DESTDIR="${D}" install
-	dodoc NEWS README AUTHORS
-	find "${D}" -name '*.la' -delete
+	)
+	autotools-utils_src_configure
 }