bump for the 0.10 slot

(Portage version: 2.2.8/cvs/Linux x86_64, signed Manifest commit with key 160F534A)

2 files changed, 281 insertions, 1 deletions

diff --git a/media-video/ffmpeg/ChangeLog b/media-video/ffmpeg/ChangeLog
index a09a4408ec22..349acda27dfd 100644
--- a/media-video/ffmpeg/ChangeLog
+++ b/media-video/ffmpeg/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-video/ffmpeg
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/ffmpeg/ChangeLog,v 1.706 2014/01/18 20:01:14 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/ffmpeg/ChangeLog,v 1.707 2014/01/19 13:48:27 aballier Exp $
+
+*ffmpeg-0.10.11 (19 Jan 2014)
+
+  19 Jan 2014; Alexis Ballier <aballier@gentoo.org> +ffmpeg-0.10.11.ebuild:
+  bump for the 0.10 slot
 
   18 Jan 2014; Agostino Sarubbo <ago@gentoo.org> ffmpeg-1.0.8.ebuild:
   Stable for alpha, wrt bug #492252
diff --git a/media-video/ffmpeg/ffmpeg-0.10.11.ebuild b/media-video/ffmpeg/ffmpeg-0.10.11.ebuild
new file mode 100644
index 000000000000..51d52421003c
--- /dev/null
+++ b/media-video/ffmpeg/ffmpeg-0.10.11.ebuild
@@ -0,0 +1,275 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/ffmpeg/ffmpeg-0.10.11.ebuild,v 1.1 2014/01/19 13:48:27 aballier Exp $
+
+EAPI="5"
+
+SCM=""
+if [ "${PV#9999}" != "${PV}" ] ; then
+	SCM="git-2"
+	EGIT_REPO_URI="git://git.videolan.org/ffmpeg.git"
+fi
+
+inherit eutils flag-o-matic multilib toolchain-funcs ${SCM} multilib-minimal
+
+DESCRIPTION="Complete solution to record, convert and stream audio and video. Includes libavcodec."
+HOMEPAGE="http://ffmpeg.org/"
+if [ "${PV#9999}" != "${PV}" ] ; then
+	SRC_URI=""
+elif [ "${PV%_p*}" != "${PV}" ] ; then # Snapshot
+	SRC_URI="mirror://gentoo/${P}.tar.bz2"
+else # Release
+	SRC_URI="http://ffmpeg.org/releases/${P/_/-}.tar.bz2"
+fi
+FFMPEG_REVISION="${PV#*_p}"
+
+LICENSE="GPL-2 amr? ( GPL-3 ) encode? ( aac? ( GPL-3 ) )"
+SLOT="0.10"
+if [ "${PV#9999}" = "${PV}" ] ; then
+	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux"
+fi
+IUSE="
+	aac aacplus alsa amr bindist +bzip2 cdio celt cpudetection debug
+	dirac doc +encode faac frei0r gnutls gsm +hardcoded-tables ieee1394 jack
+	jpeg2k libass libv4l modplug mp3 +network openal openssl oss pic pulseaudio
+	rtmp schroedinger sdl speex static-libs test theora threads
+	truetype v4l vaapi vdpau vorbis vpx X x264 xvid +zlib
+	"
+
+# String for CPU features in the useflag[:configure_option] form
+# if :configure_option isn't set, it will use 'useflag' as configure option
+CPU_FEATURES="3dnow:amd3dnow 3dnowext:amd3dnowext altivec avx mmx mmxext:mmx2 ssse3 vis neon"
+
+for i in ${CPU_FEATURES}; do
+	IUSE="${IUSE} ${i%:*}"
+done
+
+DOCS=""
+
+RDEPEND="
+	alsa? ( media-libs/alsa-lib[${MULTILIB_USEDEP}] )
+	amr? ( media-libs/opencore-amr[${MULTILIB_USEDEP}] )
+	bzip2? ( app-arch/bzip2[${MULTILIB_USEDEP}] )
+	cdio? ( dev-libs/libcdio-paranoia[${MULTILIB_USEDEP}] )
+	celt? ( >=media-libs/celt-0.11.1[${MULTILIB_USEDEP}] )
+	dirac? ( media-video/dirac[${MULTILIB_USEDEP}] )
+	encode? (
+		aac? ( media-libs/vo-aacenc[${MULTILIB_USEDEP}] )
+		aacplus? ( media-libs/libaacplus[${MULTILIB_USEDEP}] )
+		amr? ( media-libs/vo-amrwbenc[${MULTILIB_USEDEP}] )
+		faac? ( media-libs/faac[${MULTILIB_USEDEP}] )
+		mp3? ( >=media-sound/lame-3.98.3[${MULTILIB_USEDEP}] )
+		theora? ( >=media-libs/libtheora-1.1.1[encode,${MULTILIB_USEDEP}] media-libs/libogg[${MULTILIB_USEDEP}] )
+		vorbis? ( media-libs/libvorbis[${MULTILIB_USEDEP}] media-libs/libogg[${MULTILIB_USEDEP}] )
+		x264? ( >=media-libs/x264-0.0.20111017:=[${MULTILIB_USEDEP}] )
+		xvid? ( >=media-libs/xvid-1.1.0[${MULTILIB_USEDEP}] )
+	)
+	frei0r? ( media-plugins/frei0r-plugins[${MULTILIB_USEDEP}] )
+	gnutls? ( >=net-libs/gnutls-2.12.16[${MULTILIB_USEDEP}] )
+	gsm? ( >=media-sound/gsm-1.0.12-r1[${MULTILIB_USEDEP}] )
+	ieee1394? ( media-libs/libdc1394[${MULTILIB_USEDEP}] sys-libs/libraw1394[${MULTILIB_USEDEP}] )
+	jack? ( media-sound/jack-audio-connection-kit[${MULTILIB_USEDEP}] )
+	jpeg2k? ( >=media-libs/openjpeg-1.3-r2:0[${MULTILIB_USEDEP}] )
+	libass? ( media-libs/libass[${MULTILIB_USEDEP}] )
+	libv4l? ( media-libs/libv4l[${MULTILIB_USEDEP}] )
+	modplug? ( media-libs/libmodplug[${MULTILIB_USEDEP}] )
+	openal? ( >=media-libs/openal-1.1[${MULTILIB_USEDEP}] )
+	openssl? ( dev-libs/openssl[${MULTILIB_USEDEP}] )
+	pulseaudio? ( media-sound/pulseaudio[${MULTILIB_USEDEP}] )
+	rtmp? ( >=media-video/rtmpdump-2.2f[${MULTILIB_USEDEP}] )
+	schroedinger? ( media-libs/schroedinger[${MULTILIB_USEDEP}] )
+	sdl? ( >=media-libs/libsdl-1.2.13-r1[audio,video,${MULTILIB_USEDEP}] )
+	speex? ( >=media-libs/speex-1.2_beta3[${MULTILIB_USEDEP}] )
+	truetype? ( media-libs/freetype:2[${MULTILIB_USEDEP}] )
+	vaapi? ( >=x11-libs/libva-0.32[${MULTILIB_USEDEP}] )
+	vdpau? ( x11-libs/libvdpau[${MULTILIB_USEDEP}] )
+	vpx? ( >=media-libs/libvpx-0.9.6[${MULTILIB_USEDEP}] )
+	X? ( x11-libs/libX11[${MULTILIB_USEDEP}] x11-libs/libXext[${MULTILIB_USEDEP}] x11-libs/libXfixes[${MULTILIB_USEDEP}] )
+	zlib? ( sys-libs/zlib[${MULTILIB_USEDEP}] )
+	!<media-video/ffmpeg-1.2
+	!<media-video/libav-9
+	abi_x86_32? ( !<=app-emulation/emul-linux-x86-medialibs-20130224-r11
+		!app-emulation/emul-linux-x86-medialibs[-abi_x86_32(-)] )"
+# !media-libs/libpostproc
+
+DEPEND="${RDEPEND}
+	>=sys-devel/make-3.81
+	dirac? ( virtual/pkgconfig )
+	doc? ( app-text/texi2html )
+	gnutls? ( virtual/pkgconfig )
+	ieee1394? ( virtual/pkgconfig )
+	libv4l? ( virtual/pkgconfig )
+	mmx? ( dev-lang/yasm )
+	rtmp? ( virtual/pkgconfig )
+	schroedinger? ( virtual/pkgconfig )
+	test? ( net-misc/wget )
+	truetype? ( virtual/pkgconfig )
+	v4l? ( sys-kernel/linux-headers )
+"
+# faac is license-incompatible with ffmpeg
+REQUIRED_USE="bindist? ( encode? ( !faac !aacplus ) !openssl )
+	libv4l? ( v4l )
+	test? ( encode zlib )"
+
+S=${WORKDIR}/${P/_/-}
+
+pkg_setup() {
+	ewarn "This version is _terribly_ outdated with known security issues and"
+	ewarn "bugs. It is provided only for binary compatibility."
+	ewarn "Use at your own risks."
+}
+
+src_prepare() {
+	if [ "${PV%_p*}" != "${PV}" ] ; then # Snapshot
+		export revision=git-N-${FFMPEG_REVISION}
+	fi
+	epatch "${FILESDIR}/freiordl.patch"
+	epatch "${FILESDIR}/flashtest.patch"
+
+	if has_version dev-libs/libcdio-paranoia; then
+		sed -i \
+			-e 's:cdio/cdda.h:cdio/paranoia/cdda.h:' \
+			-e 's:cdio/paranoia.h:cdio/paranoia/paranoia.h:' \
+			configure libavdevice/libcdio.c || die
+	fi
+
+	epatch "${FILESDIR}"/${PN}-0.10.10-freetype251.patch
+}
+
+multilib_src_configure() {
+	local myconf="${EXTRA_FFMPEG_CONF}"
+	# Set to --enable-version3 if (L)GPL-3 is required
+	local version3=""
+
+	# enabled by default
+	for i in debug doc network vaapi vdpau zlib; do
+		use ${i} || myconf="${myconf} --disable-${i}"
+	done
+	use bzip2 || myconf="${myconf} --disable-bzlib"
+
+	use cpudetection && myconf="${myconf} --enable-runtime-cpudetect"
+	use openssl && myconf="${myconf} --enable-openssl --enable-nonfree"
+	for i in gnutls ; do
+		use $i && myconf="${myconf} --enable-$i"
+	done
+
+	# Encoders
+	if use encode
+	then
+		use mp3 && myconf="${myconf} --enable-libmp3lame"
+		use aac && { myconf="${myconf} --enable-libvo-aacenc" ; version3=" --enable-version3" ; }
+		use amr && { myconf="${myconf} --enable-libvo-amrwbenc" ; version3=" --enable-version3" ; }
+		for i in theora vorbis x264 xvid; do
+			use ${i} && myconf="${myconf} --enable-lib${i}"
+		done
+		use aacplus && myconf="${myconf} --enable-libaacplus --enable-nonfree"
+		use faac && myconf="${myconf} --enable-libfaac --enable-nonfree"
+	else
+		myconf="${myconf} --disable-encoders"
+	fi
+
+	# libavdevice options
+	use cdio && myconf="${myconf} --enable-libcdio"
+	use ieee1394 && myconf="${myconf} --enable-libdc1394"
+	use openal && myconf="${myconf} --enable-openal"
+	# Indevs
+	# v4l1 is gone since linux-headers-2.6.38
+	myconf="${myconf} --disable-indev=v4l"
+	use v4l || myconf="${myconf} --disable-indev=v4l2"
+	for i in alsa oss jack ; do
+		use ${i} || myconf="${myconf} --disable-indev=${i}"
+	done
+	use X && myconf="${myconf} --enable-x11grab"
+	use pulseaudio && myconf="${myconf} --enable-libpulse"
+	use libv4l && myconf="${myconf} --enable-libv4l2"
+	# Outdevs
+	for i in alsa oss sdl ; do
+		use ${i} || myconf="${myconf} --disable-outdev=${i}"
+	done
+	# libavfilter options
+	use frei0r && myconf="${myconf} --enable-frei0r"
+	use truetype && myconf="${myconf} --enable-libfreetype"
+	use libass && myconf="${myconf} --enable-libass"
+
+	# Threads; we only support pthread for now but ffmpeg supports more
+	use threads && myconf="${myconf} --enable-pthreads"
+
+	# Decoders
+	use amr && { myconf="${myconf} --enable-libopencore-amrwb --enable-libopencore-amrnb" ; version3=" --enable-version3" ; }
+	for i in celt gsm dirac modplug rtmp schroedinger speex vpx; do
+		use ${i} && myconf="${myconf} --enable-lib${i}"
+	done
+	use jpeg2k && myconf="${myconf} --enable-libopenjpeg"
+
+	# CPU features
+	for i in ${CPU_FEATURES}; do
+		use ${i%:*} || myconf="${myconf} --disable-${i#*:}"
+	done
+	if use pic ; then
+		myconf="${myconf} --enable-pic"
+		# disable asm code if PIC is required
+		# as the provided asm decidedly is not PIC for x86.
+		[[ ${ABI} == x86* ]] && myconf="${myconf} --disable-asm"
+	fi
+	[[ ${ABI} == "x32" ]] && myconf+=" --disable-asm" #427004
+
+	# Try to get cpu type based on CFLAGS.
+	# Bug #172723
+	# We need to do this so that features of that CPU will be better used
+	# If they contain an unknown CPU it will not hurt since ffmpeg's configure
+	# will just ignore it.
+	for i in $(get-flag march) $(get-flag mcpu) $(get-flag mtune) ; do
+		[ "${i}" = "native" ] && i="host" # bug #273421
+		myconf="${myconf} --cpu=${i}"
+		break
+	done
+
+	# Mandatory configuration
+	myconf="
+		--enable-gpl
+		${version3}
+		--enable-avfilter
+		--disable-stripping
+		${myconf}"
+
+	# cross compile support
+	if tc-is-cross-compiler ; then
+		myconf="${myconf} --enable-cross-compile --arch=$(tc-arch-kernel) --cross-prefix=${CHOST}-"
+		case ${CHOST} in
+			*freebsd*)
+				myconf="${myconf} --target-os=freebsd"
+				;;
+			mingw32*)
+				myconf="${myconf} --target-os=mingw32"
+				;;
+			*linux*)
+				myconf="${myconf} --target-os=linux"
+				;;
+		esac
+	fi
+
+	# Misc stuff
+	use hardcoded-tables && myconf="${myconf} --enable-hardcoded-tables"
+
+	"${S}"/configure \
+		--prefix="${EPREFIX}/usr" \
+		--libdir="${EPREFIX}/usr/$(get_libdir)" \
+		--shlibdir="${EPREFIX}/usr/$(get_libdir)" \
+		--mandir="${EPREFIX}/usr/share/man" \
+		--enable-shared \
+		--cc="$(tc-getCC)" \
+		--cxx="$(tc-getCXX)" \
+		--ar="$(tc-getAR)" \
+		--optflags="${CFLAGS}" \
+		--extra-cflags="${CFLAGS}" \
+		--extra-cxxflags="${CXXFLAGS}" \
+		--disable-static \
+		--disable-{ffplay,ffmpeg,ffprobe,ffserver} \
+		--disable-{swresample,postproc,swscale,avdevice} \
+		${myconf} || die
+}
+
+multilib_src_install() {
+	emake DESTDIR="${D}" install-libs
+	rm -f "${ED}"/usr/$(get_libdir)/*.so
+}