bump; clean old python impl, update SRC_URI, deps, add doc build, upgrade test phase

(Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key 0xB8072B0D)

2 files changed, 63 insertions, 1 deletions

diff --git a/dev-python/whoosh/ChangeLog b/dev-python/whoosh/ChangeLog
index 99e943decbd2..292afc134935 100644
--- a/dev-python/whoosh/ChangeLog
+++ b/dev-python/whoosh/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-python/whoosh
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/whoosh/ChangeLog,v 1.20 2014/07/27 01:23:42 idella4 Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/whoosh/ChangeLog,v 1.21 2014/11/14 03:48:52 idella4 Exp $
+
+*whoosh-2.6.0 (14 Nov 2014)
+
+  14 Nov 2014; Ian Delaney <idella4@gentoo.org> +whoosh-2.6.0.ebuild:
+  bump; clean old python impl, update SRC_URI, deps, add doc build, upgrade test
+  phase
 
   27 Jul 2014; Ian Delaney <idella4@gentoo.org> whoosh-2.5.7.ebuild:
   drop py2.6 pypy2_0 add py3.4
diff --git a/dev-python/whoosh/whoosh-2.6.0.ebuild b/dev-python/whoosh/whoosh-2.6.0.ebuild
new file mode 100644
index 000000000000..7379cb611373
--- /dev/null
+++ b/dev-python/whoosh/whoosh-2.6.0.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/whoosh/whoosh-2.6.0.ebuild,v 1.1 2014/11/14 03:48:52 idella4 Exp $
+
+EAPI="5"
+
+PYTHON_COMPAT=( python{2_7,3_3,3_4} pypy )
+
+MY_PN="Whoosh"
+
+inherit distutils-r1
+
+DESCRIPTION="Fast, pure-Python full text indexing, search and spell checking library"
+HOMEPAGE="http://bitbucket.org/mchaput/whoosh/wiki/Home/ http://pypi.python.org/pypi/Whoosh/"
+SRC_URI="mirror://pypi/W/${MY_PN}/${MY_PN}-${PV}.zip"
+
+DEPEND="app-arch/unzip
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? ( dev-python/pytest[${PYTHON_USEDEP}] )"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+python_prepare_all() {
+	# (backport from upstream)
+	sed -i -e '/cmdclass/s:pytest:PyTest:' setup.py || die
+
+	# Prevent un-needed download during build
+	sed -e "/^              'sphinx.ext.intersphinx',/d" -i docs/source/conf.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && sphinx-build -b html -c docs/source/ docs/source/ docs/source/build/html
+}
+
+# Restrict to test phase; a few random tests fail without it
+src_test() {
+	local DISTUTILS_NO_PARALLEL_BUILD=1
+	distutils-r1_src_test
+}
+
+python_test() {
+	esetup.py test
+}
+
+python_install_all() {
+	local DOCS=( README.txt )
+	use doc && local HTML_DOCS=( docs/source/build/html/. )
+	distutils-r1_python_install_all
+}