Convert to distutils-r1.

(Portage version: 2.2.0_alpha189/cvs/Linux x86_64, signed Manifest commit with key 9627F456F9DA7643!)

2 files changed, 74 insertions, 1 deletions

diff --git a/dev-python/pyudev/ChangeLog b/dev-python/pyudev/ChangeLog
index d74c0a008ccd..bf37ca6bf571 100644
--- a/dev-python/pyudev/ChangeLog
+++ b/dev-python/pyudev/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/pyudev
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/pyudev/ChangeLog,v 1.20 2013/07/21 08:50:15 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pyudev/ChangeLog,v 1.21 2013/07/26 20:45:09 mgorny Exp $
+
+*pyudev-0.16.1-r1 (26 Jul 2013)
+
+  26 Jul 2013; Michał Górny <mgorny@gentoo.org> +pyudev-0.16.1-r1.ebuild:
+  Convert to distutils-r1.
 
   21 Jul 2013; Pacho Ramos <pacho@gentoo.org> metadata.xml:
   Cleanup due #92799
diff --git a/dev-python/pyudev/pyudev-0.16.1-r1.ebuild b/dev-python/pyudev/pyudev-0.16.1-r1.ebuild
new file mode 100644
index 000000000000..0d103e3d35b8
--- /dev/null
+++ b/dev-python/pyudev/pyudev-0.16.1-r1.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pyudev/pyudev-0.16.1-r1.ebuild,v 1.1 2013/07/26 20:45:09 mgorny Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_6,2_7,3_2} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python binding to libudev"
+HOMEPAGE="http://packages.python.org/pyudev/ http://pypi.python.org/pypi/pyudev"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="pygobject pyqt4 pyside test"
+
+RDEPEND="virtual/udev
+	pygobject? ( dev-python/pygobject:2[$(python_gen_usedep 'python2*')] )
+	pyqt4? ( dev-python/PyQt4[${PYTHON_USEDEP}] )
+	pyside? ( dev-python/pyside[${PYTHON_USEDEP}] )"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? ( dev-python/mock[${PYTHON_USEDEP}] )"
+
+DOCS=( CHANGES.rst README.rst )
+
+REQUIRED_USE="pygobject? ( || ( $(python_gen_useflags 'python2*') ) )"
+
+python_prepare_all() {
+	# tests are known to pass then fail on alternate runs
+	# tests: fix run_path
+	sed -i -e "s|== \('/run/udev'\)|in (\1,'/dev/.udev')|g" \
+		tests/test_core.py || die
+
+	if ! use pygobject; then
+		rm pyudev/glib.py || die
+		sed -i -e "s|[, ]*GlibBinding()||g" \
+			tests/test_observer.py || die
+	fi
+	if ! use pyqt4; then
+		rm pyudev/pyqt4.py || die
+		sed -i -e "s|Qt4Binding('PyQt4')[, ]*||g" \
+			tests/test_observer.py || die
+	fi
+	if ! use pyside; then
+		rm pyudev/pyside.py || die
+		sed -i -e "s|Qt4Binding('PySide')[, ]*||g" \
+			tests/test_observer.py || die
+	fi
+	if ! use pyqt4 && ! use pyside; then
+		rm pyudev/_qt_base.py || die
+	fi
+	if ! use pyqt4 && ! use pyside && ! use pygobject; then
+		rm tests/test_observer.py || die
+	fi
+
+	ewarn "If your PORTAGE_TMPDIR is longer in length then '/var/tmp/',"
+	ewarn "change it to /var/tmp to ensure tests will pass."
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	py.test || die "Tests fail with ${EPYTHON}"
+}