Bump jacl to latest version.

(Portage version: 2.2_rc8/cvs/Linux 2.6.26-gentoo x86_64)

1 files changed, 50 insertions, 0 deletions

diff --git a/dev-java/jacl/jacl-1.4.1.ebuild b/dev-java/jacl/jacl-1.4.1.ebuild
new file mode 100644
index 000000000000..1de411e580bb
--- /dev/null
+++ b/dev-java/jacl/jacl-1.4.1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-java/jacl/jacl-1.4.1.ebuild,v 1.1 2008/09/14 06:16:18 ali_bush Exp $
+
+inherit base java-pkg-2
+
+DESCRIPTION="Jacl is an implementation of Tcl written in Java."
+HOMEPAGE="http://tcljava.sourceforge.net"
+MY_P="${P//-}"
+SRC_URI="mirror://sourceforge/tcljava/${MY_P}.tar.gz"
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~ia64 ~ppc ~ppc64 ~x86 ~x86-fbsd"
+IUSE="doc"
+
+RDEPEND=">=dev-lang/tcl-8.4.5
+	>=virtual/jre-1.4"
+DEPEND=">=virtual/jdk-1.4
+	${RDEPEND}"
+
+S=${WORKDIR}/${MY_P}
+
+PATCHES=( "${FILESDIR}/${P}-build.patch" )
+
+# jikes support disabled for now.
+# refer to bug #100020 and bug #89711
+
+src_compile() {
+	local jflags="$(java-pkg_javac-args)"
+	JAVAC_FLAGS="${jflags}" \
+		econf --enable-jacl --without-jikes || die
+	#ali_bush: Fails intermitently with MAKEOPTS="-j3"
+	JAVAC_FLAGS="${jflags}" \
+		MAKEOPTS="-j2" \
+		emake DESTDIR="/usr/share/${PN}" || die "emake failed"
+}
+
+src_test() {
+	emake check || die "Tests failed"
+	einfo "Some tests are known to fail. We didn't restrict them"
+	einfo "because the ebuild doesn't die."
+}
+
+src_install() {
+	#emake DESTDIR="${D}" install || die "emake install failed"
+	java-pkg_dojar *.jar
+	java-pkg_dolauncher jaclsh --main tcl.lang.Shell
+	dodoc README ChangeLog known_issues.txt || die
+	use doc && java-pkg_dohtml -r docs/*
+}