gentoolkit-0.2.4.4 version bump. This version fixes bugs 170784, 182990, 218312, 256013, 266996, and 268513. Bug 268001 tracks changes to gentoolkit-0.2.4.

gentoolkit-0.3.0_rc6 version bump. This version fixes bugs 170784, 182990, 218312, and 268895. Bug 237694 tracks changes to gentoolkit-0.3.0
(Portage version: 2.2_rc33/cvs/Linux i686)

3 files changed, 131 insertions, 1 deletions

diff --git a/app-portage/gentoolkit/ChangeLog b/app-portage/gentoolkit/ChangeLog
index 47156bf50aea..5437fc2eb3a9 100644
--- a/app-portage/gentoolkit/ChangeLog
+++ b/app-portage/gentoolkit/ChangeLog
@@ -1,6 +1,17 @@
 # ChangeLog for app-portage/gentoolkit
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-portage/gentoolkit/ChangeLog,v 1.156 2009/05/17 08:58:47 aballier Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-portage/gentoolkit/ChangeLog,v 1.157 2009/05/18 22:08:39 fuzzyray Exp $
+
+*gentoolkit-0.3.0_rc6 (18 May 2009)
+*gentoolkit-0.2.4.4 (18 May 2009)
+
+  18 May 2009; Paul Varner <fuzzyray@gentoo.org> +gentoolkit-0.2.4.4.ebuild,
+  +gentoolkit-0.3.0_rc6.ebuild:
+  gentoolkit-0.2.4.4 version bump. This version fixes bugs 170784, 182990,
+  218312, 256013, 266996, and 268513. Bug 268001 tracks changes to
+  gentoolkit-0.2.4.
+  gentoolkit-0.3.0_rc6 version bump. This version fixes bugs 170784, 182990,
+  218312, and 268895. Bug 237694 tracks changes to gentoolkit-0.3.0.
 
   17 May 2009; Alexis Ballier <aballier@gentoo.org>
   gentoolkit-0.3.0_rc5.ebuild:
diff --git a/app-portage/gentoolkit/gentoolkit-0.2.4.4.ebuild b/app-portage/gentoolkit/gentoolkit-0.2.4.4.ebuild
new file mode 100644
index 000000000000..64a3cf07291c
--- /dev/null
+++ b/app-portage/gentoolkit/gentoolkit-0.2.4.4.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-portage/gentoolkit/gentoolkit-0.2.4.4.ebuild,v 1.1 2009/05/18 22:08:39 fuzzyray Exp $
+
+EAPI=2
+
+inherit eutils python
+
+DESCRIPTION="Collection of administration scripts for Gentoo"
+HOMEPAGE="http://www.gentoo.org/proj/en/portage/tools/index.xml"
+SRC_URI="mirror://gentoo/${P}.tar.gz http://dev.gentoo.org/~fuzzyray/distfiles/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE=""
+
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 -x86-fbsd"
+
+DEPEND="sys-apps/portage
+	dev-lang/python[xml]
+	dev-lang/perl
+	sys-apps/grep"
+RDEPEND="${DEPEND}"
+
+src_install() {
+	emake DESTDIR="${D}" install-gentoolkit || die "install-gentoolkit failed"
+
+	# Create cache directory for revdep-rebuild
+	dodir /var/cache/revdep-rebuild
+	keepdir /var/cache/revdep-rebuild
+	fowners root:root /var/cache/revdep-rebuild
+	fperms 0700 /var/cache/revdep-rebuild
+}
+
+pkg_postinst() {
+	# Make sure that our ownership and permissions stuck
+	chown root:root "${ROOT}/var/cache/revdep-rebuild"
+	chmod 0700 "${ROOT}/var/cache/revdep-rebuild"
+
+	python_mod_optimize /usr/lib/gentoolkit
+
+	einfo
+	elog "The default location for revdep-rebuild files has been moved"
+	elog "to /var/cache/revdep-rebuild when run as root."
+	einfo
+	einfo "Another alternative to equery is app-portage/portage-utils"
+	einfo
+	einfo "For further information on gentoolkit, please read the gentoolkit"
+	einfo "guide: http://www.gentoo.org/doc/en/gentoolkit.xml"
+	einfo
+}
+
+pkg_postrm() {
+	python_mod_cleanup /usr/lib/gentoolkit
+}
diff --git a/app-portage/gentoolkit/gentoolkit-0.3.0_rc6.ebuild b/app-portage/gentoolkit/gentoolkit-0.3.0_rc6.ebuild
new file mode 100644
index 000000000000..dcac05144431
--- /dev/null
+++ b/app-portage/gentoolkit/gentoolkit-0.3.0_rc6.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-portage/gentoolkit/gentoolkit-0.3.0_rc6.ebuild,v 1.1 2009/05/18 22:08:39 fuzzyray Exp $
+
+EAPI=2
+
+inherit distutils
+
+DESCRIPTION="Collection of administration scripts for Gentoo"
+HOMEPAGE="http://www.gentoo.org/proj/en/portage/tools/index.xml"
+SRC_URI="mirror://gentoo/${P}.tar.gz http://dev.gentoo.org/~fuzzyray/distfiles/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE=""
+
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd"
+
+DEPEND="sys-apps/portage
+	dev-lang/python[xml]
+	dev-lang/perl
+	sys-apps/grep
+	sys-apps/gawk"
+RDEPEND="${DEPEND}"
+
+src_install() {
+	distutils_src_install
+
+	# Create cache directory for revdep-rebuild
+	dodir /var/cache/revdep-rebuild
+	keepdir /var/cache/revdep-rebuild
+	fowners root:root /var/cache/revdep-rebuild
+	fperms 0700 /var/cache/revdep-rebuild
+
+	# Gentoolkit scripts can use this to report a consistant version
+	dodir /etc
+	echo "$P" > "${D}"/etc/gentoolkit-version
+
+	# Can distutils handle this?
+	dosym eclean /usr/bin/eclean-dist
+	dosym eclean /usr/bin/eclean-pkg
+}
+
+pkg_postinst() {
+	distutils_pkg_postinst
+
+	# Make sure that our ownership and permissions stuck
+	chown root:root "${ROOT}/var/cache/revdep-rebuild"
+	chmod 0700 "${ROOT}/var/cache/revdep-rebuild"
+
+	einfo
+	elog "The default location for revdep-rebuild files has been moved"
+	elog "to /var/cache/revdep-rebuild when run as root."
+	einfo
+	einfo "Another alternative to equery is app-portage/portage-utils"
+	einfo
+	einfo "For further information on gentoolkit, please read the gentoolkit"
+	einfo "guide: http://www.gentoo.org/doc/en/gentoolkit.xml"
+	einfo
+	ewarn "This version of gentoolkit contains a rewritten version of equery"
+	ewarn "and the gentoolkit library.  Because of this, the documentation is"
+	ewarn "out of date.  Please check http://bugs.gentoo.org/269071 when"
+	ewarn "filing bugs to see if your issue is being addressed."
+}