new upstream release. fixes bug #227831.

(Portage version: 2.1.4.4)

2 files changed, 80 insertions, 1 deletions

diff --git a/mail-client/sylpheed/ChangeLog b/mail-client/sylpheed/ChangeLog
index f919bee7ea26..8b613c5ea8fd 100644
--- a/mail-client/sylpheed/ChangeLog
+++ b/mail-client/sylpheed/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for mail-client/sylpheed
 # Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/mail-client/sylpheed/ChangeLog,v 1.260 2008/06/18 07:54:18 opfer Exp $
+# $Header: /var/cvsroot/gentoo-x86/mail-client/sylpheed/ChangeLog,v 1.261 2008/06/19 15:06:12 hattya Exp $
+
+*sylpheed-2.5.0 (19 Jun 2008)
+
+  19 Jun 2008; Akinori Hattori <hattya@gentoo.org> +sylpheed-2.5.0.ebuild:
+  new upstream release. fixes bug #227831.
 
   18 Jun 2008; Christian Faulhammer <opfer@gentoo.org>
   sylpheed-2.4.8.ebuild:
diff --git a/mail-client/sylpheed/sylpheed-2.5.0.ebuild b/mail-client/sylpheed/sylpheed-2.5.0.ebuild
new file mode 100644
index 000000000000..fa8adb4d7dc9
--- /dev/null
+++ b/mail-client/sylpheed/sylpheed-2.5.0.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/mail-client/sylpheed/sylpheed-2.5.0.ebuild,v 1.1 2008/06/19 15:06:12 hattya Exp $
+
+inherit autotools eutils
+
+IUSE="crypt ipv6 ldap nls pda spell ssl xface"
+
+DESCRIPTION="A lightweight email client and newsreader"
+HOMEPAGE="http://sylpheed.sraoss.jp/"
+SRC_URI="http://sylpheed.sraoss.jp/${PN}/v${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2 LGPL-2.1"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+SLOT="0"
+
+COMMON_DEPEND=">=x11-libs/gtk+-2.4
+	nls? ( >=sys-devel/gettext-0.12.1 )
+	crypt? ( >=app-crypt/gpgme-0.4.5 )
+	ldap? ( >=net-nds/openldap-2.0.11 )
+	pda? ( app-pda/jpilot )
+	spell? ( app-text/gtkspell )
+	ssl? ( dev-libs/openssl )"
+DEPEND="${COMMON_DEPEND}
+	dev-util/pkgconfig
+	xface? ( >=media-libs/compface-1.4 )"
+RDEPEND="${COMMON_DEPEND}
+	app-misc/mime-types
+	x11-misc/shared-mime-info"
+
+AT_M4DIR="ac"
+
+src_unpack() {
+
+	unpack ${A}
+	cd "${S}"
+
+	epatch "${FILESDIR}"/${PN}-2.*.diff
+
+	use crypt || cp ac/missing/gpgme.m4 ac
+
+	eautomake
+
+}
+
+src_compile() {
+
+	local htmldir=/usr/share/doc/${PF}/html
+
+	econf \
+		$(use_enable crypt gpgme) \
+		$(use_enable ipv6) \
+		$(use_enable ldap) \
+		$(use_enable nls) \
+		$(use_enable pda jpilot) \
+		$(use_enable spell gtkspell) \
+		$(use_enable ssl) \
+		$(use_enable xface compface) \
+		--with-manualdir=${htmldir}/manual \
+		--with-faqdir=${htmldir}/faq \
+		|| die
+	emake || die
+
+}
+
+src_install() {
+
+	emake DESTDIR="${D}" install || die
+
+	dodoc AUTHORS ChangeLog* NEWS* README* TODO*
+	doicon *.png
+	domenu *.desktop
+
+}